MINIX 学习笔记

很遗憾，minix的阅读计划被我取消了

莫问春秋 — Sun, 31 Dec 2006 15:20:00 GMT

      可以说是迫于压力吧，工作这几个月来发现linux的用途太广泛了，既然这样发时间研究minix操作系统为什么不研究linux ？操作系统理论很成熟的，都是在x86上变化自然不大。
       另外一个原因就是minix本身的问题，用它来研究x86硬件体系和基础操作系统实现很适合，但是某些高级功能是不可能在它里面找到的而linux有。
      没什么好说的了，Go on!

Minix3 Context Switch实现分析

莫问春秋 — Mon, 04 Sep 2006 07:57:00 GMT

       以前我研究过ucosII的源代码，对应于x86来说，ucos是实模式下面的操作系统。而Minix是保护模式下的操作系统，自然他们的Context Switch有不一样的地方，现在，我就结合我知道的知识谈一下二者的区别。
      Context Switch是多任务操作系统必不可少的部分，它的主要任务就是保护cpu的执行现场，将cpu的寄存器保存起来。在这一点上Minix3 和ucosII是没有区别的。同时二者在实现的层面上都和堆栈有关。
      现在着重谈一下他们的区别：
      第一个首要关注的地方就是x86的硬件体系，保护模式下的内容远远比实模式丰富，研究保护模式下的操作系统，必然跟GDT、LDT、IDT发生关系。所以，保护模式下Conext Switch就要比实模式复杂些。
      ucosII在实现Context Switch时，仅仅将cpu的执行现场也就是寄存器保存在任务自己的堆栈中，保存和还原任务寄存器的功能都是通过中断机制完成的。保护模式下的Context Switch的内容就要丰富的多，首要提到的东西就是新增加的tr寄存器，tr寄存器保存的是任务状态段
TSS的段选择子。

struct tss_s
{
  reg_t backlink;
  reg_t sp0;                    /* stack pointer to use during interrupt */
  reg_t ss0;                    /*   "   segment  "  "    "        "     */
  .
  .
}
struct tss_s tss;
tss.ss0 = DS_SELECTOR;
init_dataseg(&gdt[TSS_INDEX], vir2phys(&tss), sizeof(tss), INTR_PRIVILEGE);
  gdt[TSS_INDEX].access = PRESENT | (INTR_PRIVILEGE << DPL_SHIFT) | TSS_TYPE;

可以看出，TSS段实际上就是保存一个tss_s结构。那tss_s又有什么用？
首先需要说明，保护模式下发生Context Switch时，cpu寄存器并不是保存在自己的工作堆栈中的，而是保存在进程控制块中的。

struct proc
{
  struct stackframe_s p_reg;    /* process' registers saved in stack frame */
  .
  .
}

tss_s的两个最重要的成员就是sp0和ss0。ss0用来指明任务控制块位于数据段内，sp0就指向p_reg的最高位，因为x86的堆栈是向下增加的。
这样，当中断发生时，通过tr就能够找到tss的sp0和ss0，然后就能够寻址到p_reg，中断将自动压入一些寄存器的指，另外一些则需要我们来压入,如下通过save函数。以下是一个简化的中断处理过程。

call    save
    .
    ret           !为什么是ret而不是iret，因为ret会跳到_restart然后iret(?push    _restart?)

相关代码如下：

    .align    16
save:
    cld            ! set direction flag to a known value
    pushad            ! save EAX, ECX, EDX, EBX, original ESP, EBP,
                                ! ESI, and EDI registers
    o16    push    ds        ! save ds
    o16    push    es        ! save es
    o16    push    fs        ! save fs
    o16    push    gs        ! save gs
    mov    dx, ss        ! ss is kernel data segment， tss.ss0 = DS_SELECTOR
    mov    ds, dx        ! load rest of kernel segments
    mov    es, dx        ! kernel does not use fs, gs
    mov    eax, esp    ! prepare to return
    incb    (_k_reenter)    ! from -1 if not reentering
    jnz    set_restart1    ! stack is already kernel stack
    mov    esp, k_stktop   !
    push    _restart    ! build return address for int handler
    xor    ebp, ebp    ! for stacktrace
    jmp    RETADR-P_STACKBASE(eax) !堆栈sp已经被改变了，所以只能够通过硬寻址找到返回地址

    .align    4
set_restart1:
    push    restart1    !存在中断嵌套
    jmp    RETADR-P_STACKBASE(eax)

_restart:

! 找到更高优先级的任务，并将相应任务控制块的p_reg赋值给tss.sp0

    cmp    (_next_ptr), 0        ! see if another process is scheduled
    jz    0f
    mov     eax, (_next_ptr)
    mov    (_proc_ptr), eax    ! schedule new process
    mov    (_next_ptr), 0
0:    mov    esp, (_proc_ptr)    ! will assume P_STACKBASE == 0
    lldt    P_LDT_SEL(esp)        ! enable process' segment descriptors
    lea    eax, P_STACKTOP(esp)    ! arrange for next interrupt
    mov    (_tss+TSS3_S_SP0), eax    ! to save state in process table
restart1:
    decb    (_k_reenter)
    o16    pop    gs
    o16    pop    fs
    o16    pop    es
    o16    pop    ds
    popad
    add    esp, 4        ! skip return adr(?call save?)
    iretd            ! continue process

-----------------------------------------------------------------------------------------------------------
如果随笔中有什么错误，还请大家指教。谢谢！

mpx386.asm细节小记

莫问春秋 — Thu, 31 Aug 2006 08:42:00 GMT

这只是mpx386.asm文件的一部分内容，随着学习的深入我会把余下部分的注解也写下来。不过有一点很抱歉，我的这个注解主要是写给自己看，以免以后遗忘后无从下手。所以注解未免太个人化，不太容易懂。敬请谅解！

!在阅读这份代码之前，必须了解cpu的保护模式、GDT、LDT、IDT等相关概念。
.sect .text
!*===========================================================================*
!*                MINIX                         *
!*===========================================================================*
MINIX:                ! this is the entry point for the MINIX kernel
    jmp    over_flags    ! skip over the next few bytes
    .data2    CLICK_SHIFT    ! for the monitor: memory granularity
flags:
    .data2    0x01FD        ! boot monitor flags:
                !    call in 386 mode, make bss, make stack,
                !    load high, don't patch, will return,
                !    uses generic INT, memory vector,
                !    new boot code return
    nop            ! extra byte to sync up disassembler
over_flags:

!在minix中将引导kernel也就是MINIX标签前的执行代码称之为mointor。
!The monitor sets CS to the kernel code, DS to kernel data, ES to a "flat
!4G" descriptor that address all memory simply from 0 up, and SS still
!points to the monitor's stack.

! Set up a C stack frame on the monitor stack.  (The monitor sets cs and ds
! right.  The ss descriptor still references the monitor data segment.)
    movzx    esp, sp        ! monitor stack is a 16 bit stack
    push    ebp
    mov    ebp, esp
    push    esi
    push    edi
    cmp    4(ebp), 0    ! monitor return vector is
    jz    noret        ! nonzero if return possible
    inc    (_mon_return)
noret:    mov    (_mon_sp), esp    ! save stack pointer for later return

! Copy the monitor global descriptor table to the address space of kernel and
! switch over to it.  Prot_init() can then update it with immediate effect.

    sgdt    (_gdt+GDT_SELECTOR)        ! get the monitor gdtr
    mov    esi, (_gdt+GDT_SELECTOR+2)    ! absolute address of GDT
    mov    ebx, _gdt            ! address of kernel GDT
    mov    ecx, 8*8            ! copying eight descriptors
    !_gdt是位于kernel数据段内的GDT。
    !GDT_SELECTOR（16bits）是GDT的段选择子，他的高13位是段描述符在GDT/LDT中的下标索引。
    !sgdt读出gdtr寄存器到操作数地址，gdtr = 32bitsbaseAddr +16bitsLimit。
    !(_gdt+GDT_SELECTOR+2) = gdt's baseAddr
copygdt:
eseg    movb    al, (esi)          !esi保留的是monitor的GDT的偏移地址。它不位于kernel数据段内。所以es:si
                                   !ES to a "flat 4G" descriptor that address all memory simply from 0 up
    movb    (ebx), al
    inc    esi
    inc    ebx
    loop    copygdt
    mov    eax, (_gdt+DS_SELECTOR+2)    ! base of kernel data. _gdt+DS_SELECTOR+2 = 段基址的低24位
    and    eax, 0x00FFFFFF            ! only 24 bits
    add    eax, _gdt            ! eax = vir2phys(gdt)
    mov    (_gdt+GDT_SELECTOR+2), eax    ! set base of GDT
    lgdt    (_gdt+GDT_SELECTOR)        ! switch over to kernel GDT
    !GDTR内是GDT的物理地址，而_gdt位于kernel的数据段内，所以
    !kernel's GDTR = kernel数据段的基地址+_gdt偏移地址

! Locate boot parameters, set up kernel segment registers and stack.
    mov    ebx, 8(ebp)    ! boot parameters offset
    mov    edx, 12(ebp)    ! boot parameters length
    mov    eax, 16(ebp)    ! address of a.out headers
    mov    (_aout), eax
    mov    ax, ds        ! kernel data
    mov    es, ax
    mov    fs, ax
    mov    gs, ax
    mov    ss, ax
    mov    esp, k_stktop    ! set sp to point to the top of kernel stack

! Call C startup code to set up a proper environment to run main().
    push    edx
    push    ebx
    push    SS_SELECTOR
    push    DS_SELECTOR
    push    CS_SELECTOR
    call    _cstart        ! cstart(cs, ds, mds, parmoff, parmlen)
    add    esp, 5*4

! Reload gdtr, idtr and the segment registers to global descriptor table set
! up by prot_init().

    lgdt    (_gdt+GDT_SELECTOR)
    lidt    (_gdt+IDT_SELECTOR)

    jmpf    CS_SELECTOR:csinit
csinit:
    o16    mov    ax, DS_SELECTOR
    mov    ds, ax
    mov    es, ax
    mov    fs, ax
    mov    gs, ax
    mov    ss, ax
    o16    mov    ax, TSS_SELECTOR    ! no other TSS is used
    ltr    ax                      ! LTR指令是专门用于装载任务状态段寄存器TR的指令。
                                !该指令的操作数是对应TSS段描述符的选择子。LTR指令
                                !从GDT中取出相应的TSS段描述符，把TSS段描述符的基地址
                                !和界限等信息装入TR的高速缓冲寄存器中。
    push    0            ! set flags to known good state
    popf                ! esp, clear nested task and int enable

    jmp    _main            ! main()

终于启动minix源代码阅读计划了！

莫问春秋 — Wed, 30 Aug 2006 07:40:00 GMT

好几个月前就已经决定研究一下操作系统实现，本来对于我这种初学者来说，linux应该是最适合我的了。可我无意中发现原来和linux有点关系血缘关系的minix系统，我无意抬高或贬低二者任何一个，我之所以选择minix，那是因为相对来说，我更喜欢学院派的东西。
阅读的难度相对来说，阅读linux低版本内核的难度比minix要低些。一位前辈说，大概读minix花的时间会比linux低版本内核多2倍的时间。那是因为linux源代码的阅读人群比较多，注释工作已经做得很好了。相反，minix在国内的学习人群比较少，中文化注释很少。